• BASIC
• Assembly
• Perl
• HTML
• Shell scripting
• SQL
• PL/SQL
• Javascript
• PHP
• Java
• C
• C++

;The second working assembly language program written by Erik G. Burrows
;A prime number generator that is capable of finding all the prime numbers
;up to 4 billion, and uses only registers to do so, except when printing
;them, which it does in decimal.

.MODEL SMALL                          ;One Data and One Code Segment
.386                                  ;Enable 32 bit register usage
.STACK                                ;A 1k stack
.CODE                                 ;Code segment
.STARTUP                              ;Entry point
MOV EAX, 1                            ;The first number
JMP FoundPrime                        ;One is prime, print it
NewNum:                               ;Next Number
  INC   EAX                           ;Advance number 
  MOV   EBX, 1
BeginTest:                            ;Start test loop
  INC   EBX                           ;Advance divisor
  CMP   EAX, EBX                      ;Check if number = divisor
  JE    FoundPrime                    ;If so, it's prime, loop finished
  MOV   ECX, EAX                      ;Save the number
  XOR   EDX, EDX                      ;Zero high DWord of divisor
  DIV   EBX                           ;Divide number by divisor
  XCHG  EDX, ECX                      ;Prep remainder for testing 
  MOV   EAX, EDX                      ;Put number back
  JCXZ  NewNum                        ;If no renainder it's not prime
  JMP   BeginTest                     ;Next in test loop
FoundPrime:                           ;Print the prime number
  MOV   EBX, EAX                      ;Store current number
  MOV   ESI, 10                       ;Load divisor with 10
  XOR   ECX, ECX                      ;Zero digit count
NON_ZERO:                             ;Calculate digits
  XOR   EDX, EDX                      ;Zero high DWord of divisor
  DIV   ESI                           ;Divide number by divisor
  PUSH  EDX                           ;Put the digit on the stack
  INC   ECX                           ;Add one more digit to count
  OR    EAX, EAX                      ;Check for end of loop
  JNE   NON_ZERO                      ;Next digit to print
  MOV   EAX, EBX                      ;Restore the current number
WRITE_DIGIT_LOOP:                     ;Print digits
  POP   EDX                           ;Get digit in reverse order
  ADD   DL,"0"                        ;Add ascii 0 to the value
  MOV   SI, AX                        ;Store ascii value
  MOV   AH,2                          ;Function 2h
  INT   21h                           ;Print it
  MOV   AX, SI                        ;Restore the ascii value
  LOOP  WRITE_DIGIT_LOOP              ;Next digit to print
  MOV   DL, " "                       ;A space
  MOV   ECX, EAX                      ;Store the current number
  MOV   AH,2                          ;Function 2h
  INT   21h                           ;Print it
  MOV   EAX, ECX                      ;Restore the test number
  JMP   NewNum                        ;Go next number
.EXIT                                 ;Exit (never gets executed)
END                                   ;End address